*image startripper.jpg

*comment image courtesy of the free license from Canva dot com

*page_break STAR TRIPPER

*set sound false

*check_achievements

*if choice_achieved_first_timer = true
	*set sound true 

*if sound
	*sound magicbell.wav

*page_break STAR TRIPPER

*if choice_achieved_first_timer = false
	*achieve first_timer
	*gosub first_time

*if choice_achieved_rescue_started = false
	[i]You must first rescue your ${brother} in order to unlock Text Arcade mode[/i]

[b]:::[/b] Choose one:

*fake_choice
	#Story mode
		*set story_mode true
		*goto_scene story_mode
	*selectable_if (choice_achieved_rescue_started = true) #Text Arcade mode
		*set sound true
		*set story_mode false
		
*label arcade_mode

[i]What is your name, Captain?[/i]

*input_text name

*label ship_namer

[i]And what is the name of your ship?[/i]

*input_text ship_name

*set ship_name "[i]${ship_name}[/i]"

[i]And how do you normally say hello to people, Captain ${name}?[/i]

*input_text greetings

[i]And which emoji would you say bests suits you?[/i]

*fake_choice
	#👨‍✈️
		*set player_emoji "👨‍✈️"
	#👩‍✈️
		*set player_emoji "👩‍✈️"
	#🧑‍🎨
		*set player_emoji "🧑‍🎨"
	#🐴
		*set player_emoji "🐴"
	#🦄
		*set player_emoji "🦄"
		
*label begin

[i]Now creating universe...[/i]

*gosub_scene randomizer

*page_break BEGIN GAME

*set game_started true

*check_achievements
*if choice_achieved_arcade_mode = false
	*achieve arcade_mode

*goto_scene startrip_main

*label first_time

*set sound true

[b]A BRIEF NOTE FROM THE AUTHOR[/b]

Hello!

It looks like this is your first time playing [i]Star Tripper[/i].

The version you are playing was designed for the IFComp 2022 competition.  As such, some features are locked until you complete the main story quest.  

[i]Star Tripper[/i] was inspired by the 2002 game for Palm OS called "Space Trader" but includes a lot of extra features, side missions, and bonuses entirely of my own design.  Furthermore, [i]Star Tripper[/i] heavily employs the use of procedural generation, so if you reset your game, everything will be different the next time around!

All errors are my responsibility, but a huge shoutout goes to [i]intfiction.org[/i] user who goes by the name [b]Uncle David[/b] who spent dozens of hours beta testing the game and giving me invaluable feedback.

Please note that the sound is turned ON by default (the sound's volume is determined by your computer/device).  During gameplay, if the sound conks out on you, you can turn the sound OFF and then ON again to reset it.

If you wish to disable the sound effects, click "Show Stats" in the upper left-hand corner of your screen at any time.  [i]Star Tripper[/i] can be played in its entirety without the use of sound effects, but I feel that they really do enhance the experience.  

Thanks, and enjoy!

[i]-Sam Ursu[/i]

*page_break

*return