the cozy_kitchen isa location
	name Kitchen
	is not visited.
	description "Pots and pans hang on hooks above a countertop covered
	in colorful vinyl, which sits between a cast iron sink full of
	dirty dishes and an antique gas stove with a hot plate on top,
	all of it opposite from a wobbly cot. A doorway leads further
	west into the house, and you can go straight out into the
	street to the east. The walls are dirty -- varnish must be
	hard to come by these days -- but the floor is bare cement,
	and spotless."
	if this is not visited then
		"$pIf anyone has heard you picking the lock and coming in,
		there's no sign of it. You stand perfectly still for a
		moment, holding your breath; the house sounds empty."
		make this visited.
	end if.
	verb knock does only
		"You're on the inside already, as for knocking on wood,
		it's kinda late for that too, now."
	end verb.
	exit east, e, out to nameless_alley
		check kitchen_door is not locked
		else "There's a locked door in the way."
		does
			if kitchen_door is not open then
				make house_door open.
				make kitchen_door open.
				"(first opening the door)"
			end if.
	end exit.
	exit west, w to storage_room.
end the cozy_kitchen.

the kitchen_door isa door at cozy_kitchen
	name wooden door
	name latch
	name gap
	name crack
	name lock
	has otherside house_door.
	has key none.
	is with_known_key.
	description
	verb examine does only
		"From inside you can easily set the latch by hand."
	end verb.
	verb lock
		check this is not locked
			else say the this. "is already locked."
		does only
			if this is open then
				make this not open.
				make otherside of this not open.
				"(first closing " say the this. ")$p"
			end if.
			make this locked.
			make otherside of this locked.
			"You lock " say the this. "."
	end verb.
	verb unlock
		check this is locked
			else say the this. " is already unlocked."
		does only
			make this not locked.
			make otherside of this not locked.
			"You unlock " say the this. "."
	end verb.
	verb knock_on does only
		"You're on the inside already, as for knocking on wood,
		it's kinda late for that too, now."
	end verb.
end the kitchen_door.

the dish_pile isa object at cozy_kitchen
	name dirty dishes
	description
	verb 'do', wash does only
		"The water tap gurgles, but yields no liquid. It will
		have to wait."
	end verb.
end the dish_pile.

the kitchen_stuff isa object at cozy_kitchen
	name kitchen fixtures
	name countertop
	name counter
	name pots
	name pans
	name pot
	name pan
	name wobbly cot
	name bed
	name bare cement floor
	name dirty walls
	name dirty wall
	name window
	name cabinet
	name cabinets
	description
end the kitchen_stuff.

the stove isa object at cozy_kitchen
	name antique gas stove
	description
	verb examine, 'use' does only
		"It's useless nowadays, of course, but certainly pretty.
		He would have loved to cook on it."
	end verb.
end the stove.

the hot_plate isa object at cozy_kitchen
	name hot plate
	is portable.
	description
	verb examine does only
		"It's an old, refurbished hot plate, presumably meant
		to supplant the now-useless gas stove (itself a real
		antique). The power cord disappears through a hole in
		the nearby wall."
	end verb.
	verb take does only
		if red_button is depressed then
			"It's attached to the wall with a thick power
			cord that vanishes into a hole."
		else
			"The hot plate zaps you. Ouch! So much for
			insulation."
		end if.
	end verb.
	verb turn_on, turn_off, toggle, 'use' does only
		"You consider making a cup of tea or something, but as it
		turns out, there's no water on tap."
	end verb.
end the hot_plate.

the kitchen_sink isa object at cozy_kitchen
	name cast iron kitchen sink
	description
	verb examine does only
		"It looks as old as the house -- over a century."
	end verb.
	verb look_under does only
		"On a closer look, the old sink turns out to have
		brand new flexible pipes that go through a rough hole
		in the wall."
	end verb.
end the kitchen_sink.

the storage_room isa location
	name Storage Room
	description "The shadows are long and deep in this room where
	the only light comes from doorways at opposite ends. Broken
	furniture clutters an otherwise generous space. A large bed
	frame is propped up against the wall; a once-elegant dresser
	gathers dust in a corner. A bedsheet hangs over something
	large, flapping slowly in an air current you can't feel.
	$pThere's a sensation of cold coming from the north; east is
	the kitchen and you can also go west into a hallway."
	exit east, e, kitchen to cozy_kitchen.
	exit west, w, hallway to tiny_hallway.
	exit north, n to cold_corridor.
end the storage_room.

the furniture isa object at storage_room
	name broken furniture
	name bed
	name bed frame
	name bed sheet
	name dresser
	name bedsheet
	description
	verb search, look_behind, look_under does only
		"All you find is dust bunnies, layers of dust and floating
		particles that make you sneeze."
	end verb.
end the furniture.

the tiny_hallway isa location
	name Tiny Hallway
	description "It's just a tiny hallway, that opens into a
	bathroom to the south and a bedroom to the west. Only a
	dark room lies to the east."
	exit east, e to storage_room.
	exit west, w to cozy_bedroom.
	exit south, s to cramped_bathroom.
end the tiny_hallway.

the cramped_bathroom isa location
	name Cramped Bathroom
	description "A minuscule window high on the wall illuminates
	fixtures sized for children; there's no room for anything
	larger anyway. You can go out to the north.
	$pA cracked mirror hangs above the sink, throwing fragments
	of reflection back at you."
	exit north, n, out to tiny_hallway.
end the cramped_bathroom.

the cracked_mirror isa object at cramped_bathroom
	name cracked mirror
	name reflection
	is portable.
	description
	verb examine does only
		"In the low light, your fragmented reflection seems to
		move by itself. You try to recognize yourself in it
		and fail."
	end verb.
	verb take does only
		"It's securely screwed to the wall, but you give it an
		experimental tug anyway. A sharp pain slashes across your
		fingertips, but when you look, there's no blood. Not even
		a cut. From the mirror, your reflection looks disapprovingly."
	end verb.
end the cracked_mirror.

the fixture isa object at cramped_bathroom
	name bathroom fixtures
	name fixture
	name sink
	name toilet
	name shower
	name bathroom
	description
	verb 'use' does only
		"Better not. There's no running water."
	end verb.
end the fixture.

the cozy_bedroom isa location
	name Cozy Bedroom
	is not visited.
	description "Half the room is taken by a soft bed with a
	threadbare blanket on it; there is a coatrack on the wall
	opposite the window and a small bookshelf in the corner.
	On a desk are scattered mismatched pieces of paper.
	$pThe window faces north, and you can go back east into
	the hallway."
	if this is not visited then
		"$pYou falter on the threshold. This whole room smells like him.
		If there was any doubt left, now it's gone. You really found
		him again! You can only hope he'll want you back in his life,
		after you didn't approve of his years-long quest."
		make this visited.
	end if.
	exit east, e, hallway to tiny_hallway.
	exit north, n to empty_backyard
		does "Should you? Why not! Grinning impishly, you climb onto
		the windowsill and jump out. Oops, it's higher than it seems --
		half a story, maybe. But you land safely on the packed earth."
	end exit.
	verb smell does only
		"It smells like home. Only it's not your home. And there's
		no-one else to blame for that."
	end verb.
end the cozy_bedroom.

the bookshelf isa object at cozy_bedroom
	name small bookshelf
	name small book shelf
	name books
	name book
	name little prince
	description
	verb examine does only
		"It's mostly do-it-yourself and engineering books, scavenged
		from who-knows-where, but also some fiction, like a thin,
		worn-out edition of The Little Prince in the original French."
	end verb.
	verb take does only
		"You browse idly through a couple of books, then put them back.
		This is not the time."
	end verb.
	verb read does only
		"The contents of most books on the shelf flies right over
		your head, to be honest."
	end verb.
end the bookshelf.

the desk isa object at cozy_bedroom
	name desk
	name table
	name paper
	name papers
	name blueprints
	name notes
	is portable.
	description
	verb examine does only
		"The papers are covered in blueprints and notes. You recognize
		his handwriting. Still crafty as always."
	end verb.
	verb take does only
		"You gently hold a few of the sheets for a moment, your hands
		shaking, then set them back down."
	end verb.
	verb read does only
		"You could never decipher his handwriting, and the blueprints
		are a maze of lines to you."
	end verb.
end the desk.

the coatrack isa object at cozy_bedroom
	name coatrack
	name jacket
	is portable.
	description
	verb examine does only
		"You recognize that jacket! It's the one you bought for him
		on your last date. Frayed and stained now, but no other."
	end verb.
	verb take does only
		"You brush your fingers along the jacket, feeling the rough,
		unequal fiber -- the ravages of time. A reminder of how much
		you missed out on. But you leave it there."
	end verb.
	verb sniff_at does only
		"You allow yourself to become lost in that ghost of his
		presence for a moment."
	end verb.
end the coatrack.

the soft_bed isa object at cozy_bedroom
	name soft bed
	name threadbare blanket
	description
end the soft_bed.

the bedroom_window isa object at cozy_bedroom
	name window
	description
	verb search does only
		"Through the window you see some sort of unpaved backyard."
	end verb.
	verb climb does only
		"Should you? Why not! Grinning impishly, you climb onto the
		windowsill and jump out. Oops, it's higher than it seems --
		half a story, maybe. But you land safely on the packed earth."
		locate hero at empty_backyard.
	end verb.
end the bedroom_window.

the iron_key isa object at cozy_bedroom
	name big heavy iron key
	is portable.
	description "$pA key has been dropped here."
end the iron_key

the cold_corridor isa location
	name Cold Corridor
	description "This poorly-lit corridor is plagued by a permanent
	cold draft. Incidentally, this makes it a good place to store
	food, as evidenced by the various cans, bags and bottles strewn
	on rickety shelves.
	$pNarrow metallic stairs lead down into darkness, while a beefier staircase leads up; you can go south into an even darker room
	and west into what must be the backyard."
	exit south, s to storage_room.
	exit west, w, out to empty_backyard.
	exit up, u to machine_room.
	exit down, d to basement
		does "The old wooden stairs vibrate dangerously as you
		descend. It feels like a long way down."
	end exit.
end the cold_corridor.

the storage isa object at cold_corridor
	name rickety shelves
	name rickety shelf
	name food
	name cans
	name bags
	name bottles
	name 'can'
	name bag
	name bottle
	description
	verb examine does only
		"You can't think of many people who would get to the trouble
		to get all these goods nowadays. It has to be his work."
	end verb.
	verb look_behind does only
		"The wall behind the shelves is pockmarked by holes.
		Pipes and cables snake out of them and go into the ceiling.
		In the background you can barely make out the boarded-up
		gate."
	end verb.
	verb take does only
		"You rummage in delight through the yummy canned goods,
		wondering where you can even get all of it these days, but
		then you carefully put everything back the way it was.
		Cooking is rather low on the list of priorities right now."
	end verb.
end the storage.

the corridor_stuff isa object at cold_corridor
	name background items
	name wall
	name walls
	name pipe
	name pipes
	name cable
	name cables
	name ceiling
	name gate
	description
end the corridor_stuff.

the basement_stairs_down isa object at cold_corridor
	name narrow metallic stairs
	name narrow metallic steps
	is portable.
	description
	verb climb does only
		"The old metallic stairs vibrate dangerously as you
		descend. It feels like a long way down."
		locate hero at basement.
	end verb.
	verb take does only
		"The old metallic stairs vibrate dangerously as you
		descend. It feels like a long way down."
		locate hero at basement.
	end verb.
end the basement_stairs_down.

the staircase_up isa object at cold_corridor
	name beefier staircase
	name beefier stairwell
	is portable.
	description
	verb climb does only locate hero at machine_room. end verb.
	verb take does only locate hero at machine_room. end verb.
end the staircase_up.

the light_switch isa device at cold_corridor
	name light switch
	name light
	is broken.
	has broken_msg "You fiddle with the switch, but nothing happens.
		Power must be out.".
	description "$pThere's a light switch by the basement stairs."
	verb examine does only
		if this is turned_on then
			"Right now it's in the 'on' position."
		else
			"Right now it's in the 'off' position."
		end if.
	end verb.
	verb turn_on, turn_off, toggle, flip does before
		if this is not broken then
			schedule switch_flipped after 0.
		end if.
	end verb.
end the light_switch.

event switch_flipped
	if light_switch is turned_on then
		make basement not dark.
		make dark_tunnel not dark.
		"A faint orange light comes from downstairs."
	else
		make basement dark.
		make dark_tunnel dark.
		"Downstairs it gets even darker that before."
	end if.
end event.

when black_button is depressed then
	make light_switch not broken.
	if light_switch is turned_on then
		make basement not dark.
		make dark_tunnel not dark.
	else
		make basement dark.
		make dark_tunnel dark.
	end if.
end when.

when red_button is depressed then
	make light_switch broken.
	make basement dark.
	make dark_tunnel dark.
end when.

the empty_backyard isa location
	name 'Empty' Backyard
	description "The backyard is just an empty patch of dirt where
	several old buildings come back to back, not quite touching
	each other. Through open windows overhead you can hear
	children laughing, or a broom scrapping on wooden floors...
	a radio being tuned... the sounds of life.
	$pYou can only go back into the house to the east."
	verb listen does only
		"Clearly the city is far from the wasteland it
		appears at first blush, by the sound of it."
	end verb.
	verb yell does only
		"You try to draw somebody's, anybody's attention, but
		to no avail."
	end verb.
	exit east, e, 'in' to cold_corridor.
end the empty_backyard.

the backyard_stuff isa object at empty_backyard
	name old buildings
	name old building
	name open windows
	name open window
	description
	verb examine does only
		"You can't see any movement at the windows, but all the
		sounds make it obvious there is life behind them."
	end verb.
end the backyard_stuff.

the backyard_sounds isa object at empty_backyard
	name sounds
	name sound
	name laughter
	name radio
	name music
	name scrapping
	description
	verb examine does only
		"You can't see where any of the sounds come from."
	end verb.
	verb listen_to does only
		"Clearly the city is far from the wasteland it
		appears at first blush, by the sound of it."
	end verb.
end the backyard_sounds.

the steel_bar isa object at empty_backyard
	name flat steel bar
	name lever
	is portable.
	description
		"$pA flat steel bar is lying around."
	verb examine does only
		"It's beginning to rust, but still sturdy."
	end verb.
end the steel_bar.

the machine_room isa location
	name Machine Room
	description "This floor has had its interior walls removed
	to make room for various paraphernalia. One side of it is taken up by
	water tanks and pumps caught in a maze of pipes; the other, by
	several boxes with thick electrical cables going in and out of them.
	$pA few steps lead further up, while a beefier staircase
	climbs down to the ground floor."
	exit down, d to cold_corridor.
	exit up, u to rooftop.
end the machine_room.

the staircase_down isa object at machine_room
	name beefier staircase
	name beefier stairwell
	is portable.
	description
	verb climb does only locate hero at cold_corridor. end verb.
	verb take does only locate hero at cold_corridor. end verb.
end the staircase_down.

the plumbing isa object at machine_room
	name plumbing
	name water tanks
	name water pipes
	name water pumps
	name water tank
	name water pipe
	name water pump
	name maze
	description
	verb examine does only
		"Part of the plumbing has been dismantled for some reason.
		That would explain the lack of water on tap downstairs."
	end verb.
end the plumbing.

the circuit_box isa object at machine_room
	name circuit box
	name circuit boxes
	name thick electrical cables
	name thick electrical cable
	name dials
	name dial
	description
	verb examine, read does only
		"The circuit boxes sport various dials, not that you know
		what they mean."
		if red_button is depressed then
			"Right now the needles are all immobile, pointing
			at zero."
		else
			"All the needles are vibraring softly around the
			midpoint of their respective scales."
		end if.
	end verb.
end the circuit_box.

the rooftop_steps_up isa object at machine_room
	name steps
	name stairs
	is portable.
	description
	verb climb does only locate hero at rooftop. end verb.
	verb take does only locate hero at rooftop. end verb.
end the rooftop_steps_up.

the rooftop isa location
	name On 'the' Roof
	description "You are on a platform floating in a sea of
	identical rooftops. Next to you is a small wind turbine;
	a couple of solar collectors complete the ensemble.
	$pOff to the side, a few steps lead down into the house."
	exit down, d to machine_room.
end the rooftop.

the rooftop_steps_down isa object at rooftop
	name steps
	name stairs
	is portable.
	description
	verb climb does only locate hero at machine_room. end verb.
	verb take does only locate hero at machine_room. end verb.
end the rooftop_steps_down.

the sollar_collector isa object at rooftop
	name solar collectors
	name solar collector
	description
end the sollar_collector.

the other_rooftops isa object at rooftop
	name rooftops
	description
end the other_rooftops.

the wind_turbine isa object at rooftop
	name small wind turbine
	description
	verb examine does only
		"The wind turbine is a patchwork job, but well-maintained,
		and solidly anchored to the roof. There's a box at the base
		of the pole, with two buttons on it.$p"
		if red_button is depressed then
			"The wind turbine isn't spinning, despite the wind."
		else
			"The wind turbine is spinning leisurely in the wind."
		end if.
	end verb.
end the wind_turbine.

the stop_switch isa object at rooftop
	name 'stop' switch
	name box
	name buttons
	description
	verb examine does only
		"On the box there's " say an red_button.
		" and " say an black_button. "."
	end verb.
end the stop_switch.

the red_button isa object at rooftop
	name big red button
	is depressed.
	mentioned
		"big red button"
		if this is depressed then "(currently depressed)" end if.
	description
	verb press, push does only
		if this is depressed then
			"It's already depressed all the way in."
		else
			"You press the big red button; the small black
			one pops out. With a screech, the wind turbine
			slows down and stops."
			make this depressed.
			make black_button not depressed.
		end if.
	end verb.
end the red_button.

the black_button isa object at rooftop
	name small black button
	is not depressed.
	mentioned
		"small black button"
		if this is depressed then "(currently depressed)" end if.
	description
	verb press, push does only
		if this is depressed then
			"It's already depressed all the way in."
		else
			"You press the small black button; the big red one
			one pops out. Slowly but surely, the wind turbine
			turns into the wind and starts spinning."
			make this depressed.
			make red_button not depressed.
		end if.
	end verb.
end the black_button.