the basement isa darkroom
	description "A 25-Watt lightbulb casts its sickly yellow light
	on ancient brick walls. The vaulted ceiling soars above a hundred
	square meters of packed earth. In all cardinal directions,
	semicircular arches lead away into darkness. The air is dry
	and still, though a little damp smell seeps in from somewhere.
	$pLittle square holes in the floor indicate where furniture
	used to be, but there's little trace of it now. Narrow stairs
	lead up."
	verb smell does only
		"The smell seems to be coming from the east."
	end verb.
	exit north, n, south, s, west, w to basement
		does "The arch runs into a literal brick wall after
		half a meter."
	end exit.
	exit up, u to cold_corridor.
	exit east, e to dark_tunnel.
end the basement.

the basement_stuff isa object at basement
	name lightbulb
	name light bulb
	name sickly yellow light
	name packed earth
	name floor
	name vaulted ceiling
	name little square holes
	description
	verb examine does only
		"It all looks as if he's been looking for buried treasure.
		The fool's errand you two argued over in the first place."
	end verb.
end the basement_stuff.

the brick_arch isa object at basement
	name brick walls
	name brick arches
	name brick arch
	name bricks
	name brick
	name brickwork
	description
	verb examine does only
		"Three of the arches run into literal brick walls after
		half a meter, but a tunnel opens into the east one."
	end verb.
end the brick_arch.

the tunnel_mouth isa object at basement
	name tunnel
	description
	verb enter does only
		locate hero at dark_tunnel.
	end verb.
	verb examine does only
		"The tunnel looks like it's been recently unearthed."
	end verb.
end the tunnel_mouth.

the dark_tunnel isa darkroom
	name Dark Tunnel
	is not visited.
	description "Meager light seeps in from a semicircular
	archway to the west. The low rumbling of running water
	reverberates throughout the curved walls; the air is damp.
	$pThe east end of the tunnel is in total darkness."
	if this is not visited then
		"The rabbit hole just got deeper. Did you uncover a trace
		after all, love? Was I wrong to doubt you?"
		make this visited.
	end if.
	verb listen does only
		"You decide what you're hearing must be water from
		the recent rains flowing through the sewers."
	end verb.
	exit west, w to basement.
	exit east, e to boiler_room
		check tunnel_door is not locked
		else "There's a locked door in the way."
		does
			if tunnel_door is not open then
				make tunnel_door open.
				make boiler_door open.
				"(first opening the door)"
			end if.
	end exit.
end the dark_tunnel.

the archway isa object at dark_tunnel
	name semicircular archway
	name semicircular arch
	name semicircular opening
	description
	verb enter does only
		locate hero at basement.
	end verb.
	verb examine does only
		"The opening looks like it's been recently unearthed."
	end verb.
end the archway.

the tunnel_door isa door at dark_tunnel
	name steel door
	name lock
	has key iron_key.
	has otherside boiler_door.
	description
	verb knock_on does only
		"Your knuckles rapping on the steel door fill the tunnel
		with an infernal din, but after the echoes die down there's
		no reaction."
	end verb.
end the tunnel_door.

the water_noise isa object at dark_tunnel
	name rumbling sound
	name rumbling noise
	name running water
	name rumbling
	description
	verb listen_to does only
		"It must be water from the recent rains
		flowing through the sewers."
	end verb.
end the water_noise.

the boiler_room isa location
	name Boiler Room
	is not navigated.
	description "Pipes run everywhere around in crazy patterns,
	valves and meters jutting out of them at odd angles, but all you
	can see is their shadows. Off to a side, a shapeless lump lies
	along the wall.
	$pA rusty door leads west, but the one to the south is missing,
	which is fortunate as that's where the only light comes from."
	verb knock does only
		"You consider causing some more noise in the adjacent
		tunnel, but that would be kind of childish."
	end verb.
	exit west, w to dark_tunnel
		check boiler_door is not locked
		else "There's a locked door in the way."
		does
			if boiler_door is not open then
				make tunnel_door open.
				make boiler_door open.
				"(first opening the door)"
			end if.
	end exit.
	exit south, s to basement_hallway
		check boiler_room is navigated
		else "You try to make your way to the doorway, but your
			clothes snag on bits of metal. You trip and
			almost fall. Deep breath. Nothing to do but try
			again."
			make boiler_room navigated.
		does
			"With some care, you manage to navigate the maze
			after all."
	end exit.
end the boiler_room.

the boiler_door isa door at boiler_room
	name steel door
	name lock
	has key iron_key.
	has otherside tunnel_door.
	description
	verb knock_on does only
		"You consider causing some more noise in the adjacent
		tunnel, but that would be kind of childish."
	end verb.
end the boiler_door.

the boiler_meter isa object at boiler_room
	name meters
	name meter
	description
	verb examine, read does only
		"It's too dark to see the meters clearly."
	end verb.
end the boiler_meter.

the boiler_stuff isa object at boiler_room
	name pipes
	name pipe
	name valves
	name valve
	name walls
	name wall
	name patterns
	name pattern
	name shadows
	name shadow
	description
	verb examine does only
		"It's too dark in the room to get a good look at anything."
	end verb.
end the boiler_stuff.

the mattress isa object at boiler_room
	name shapeless lump
	name lumpy dirty mattress
	is portable.
	description
	verb examine does only
		"On a closer examination, it turns out to be an old lumpy
		mattress. Quite dirty, too. Hasn't been used recently."
	end verb.
	verb look_under does only
		"All you find under the mattress is more grime."
	end verb.
	verb take does only
		"Yuck. It's filthy."
	end verb.
end the mattress.

the basement_hallway isa location
	name Basement Hallway
	description "A small, dirty window right under the low ceiling
	lets in enough light to see the blue-green paint on the
	cracked walls, and the pile of broken old furniture at the
	other end of the hallway. There is a musty smell in the air,
	hanging like a ghost in the stillness.
	$pAn oak door leads south. The one in the north wall is
	absent."
	verb knock does only
		"Knocking on the door elicits no reaction from inside."
	end verb.
	verb smell does only
		"The smell is quite strong. The basement must have been
		flooded at the last rain. It poured down hard enough."
	end verb.
	exit north, n to boiler_room.
	exit south, s to basement_apartment
		check basement_door is not locked
		else "There's a locked door in the way."
		does
			if basement_door is not open then
				make basement_door open.
				make apartment_door open.
				"(first opening the door)"
			end if.
	end exit.
end the basement_hallway.

the basement_door isa door at basement_hallway
	name oak door
	name lock
	has key none.
	has otherside apartment_door.
	description
	verb examine does only
		"On a closer look, the door doesn't seem to be locked, just
		stuck. You only need a little extra leverage to get it open."
	end verb.
	verb push does only
		"You put your shoulder to the door and shove, but it doesn't
		quite yield. It will take more than your bare hands."
	end verb.
	verb knock_on does only
		"Knocking on the door elicits no reaction from inside."
	end verb.
	verb put_in when obj2
		check basement_door is locked
			else "You've already gotten the door unstuck."
		does only
			if obj <> steel_bar then
				say the obj. "doesn't look strong enough."
			else
				make basement_door not locked.
				make apartment_door not locked.
				"You slide the steel bar between door and
				doorjamb, and pull. The wood groans and
				creaks, but finally yields, and the door
				becomes unstuck."
			end if.
	end verb.
	verb open_with when obj
		check basement_door is locked
			else "You've already gotten the door unstuck."
		does only
			if obj2 <> steel_bar then
				say the obj2. "doesn't look strong enough."
			else
				make basement_door not locked.
				make apartment_door not locked.
				"You slide the steel bar between door and
				doorjamb, and pull. The wood groans and
				creaks, but finally yields, and the door
				becomes unstuck."
			end if.
	end verb.
end the basement_door.

the basement_walls isa object at basement_hallway
	name cracked walls
	name cracked wall
	name blue green paint
	description
	verb examine does only
		"The walls carry signs of past flooding around ankle height."
	end verb.
end the basement_walls.

the basement_hall_stuff isa object at basement_hallway
	name small dirty window
	name low ceiling
	name light
	description
	verb examine does only
		"Looking up doesn't yield any insights."
	end verb.
end the basement_hall_stuff.

the basement_furniture isa object at basement_hallway
	name broken old furniture
	description
	verb examine does only
		"It's been there for a long time, judging by the layer of
		dust and the water damage."
	end verb.
	verb look_behind does only
		"There used to be a way up to ground floor, but it's now
		completely blocked by the broken furniture."
	end verb.
end the basement_furniture.

the basement_apartment isa location
	name Basement Apartment
	is not visited.
	has searches 0.
	description "The silence is deafening in what must have been
	once a cozy little home, with heavy furniture carrying the
	unmistakable dignity of a past age. The walls are plastered
	with bookshelves, and more pile up on the coffee table and
	armchairs; there is a kitchenette and a small shower, though it
	would be a wonder if anything still worked. In any event, there
	doesn't seem to be any water or electrical power.
	$pDust covers every possible surface, and a damp smell hangs
	in the air. It's a wonder all those books haven't
	disintegrated yet. The exit is an oak door to the north."
	if this is not visited then
		"$pCould this be the place? The one he was looking for when
		you... left? But if he found it, then why...? No, he must
		have failed to find his little treasure. That's why he's
		still out here instead of home with you.
		$pMaybe you can make the great discovery for him, right in
		this room."
		make this visited.
	end if.
	verb smell does only
		"Oddly enough, there is no sign of water damage in the room.
		The smell must be seeping in from outside."
	end verb.
	verb knock does only
		"There are many different things to knock on, around here."
	end verb.
	verb listen does only
		"It's quiet all right. The quiet of a tomb where buried
		memories lie still."
	end verb.
	exit north, n, out to basement_hallway
		check apartment_door is not locked
		else "There's a locked door in the way."
		does
			if apartment_door is not open then
				make basement_door open.
				make apartment_door open.
				"(first opening the door)"
			end if.
	end exit.
end the basement_apartment.

the apartment_door isa door at basement_apartment
	name oak door
	name lock
	has key none.
	has otherside basement_door.
	description
	verb knock_on does only
		"Seeing as you're already on the inside, knocking on the
		door is unlikely to be productive."
	end verb.
end the apartment_door.

the apartment_furniture isa object at basement_apartment
	name heavy furniture
	description
	verb examine does only
		"There's a variety of furniture here, that warrants
		a closer look."
	end verb.
end the apartment_furniture.

the apartment_walls isa object at basement_apartment
	name walls
	name wall
	name wallpaper
	is not searched.
	description
	verb examine does only
		"The walls are covered in faded, peeling wallpaper, as far
		as you can see behind the bookshelves."
	end verb.
	verb search, look_behind does only
		if this is searched then
			"You've already checked" say the this. "."
		else
			make this searched.
			increase searches of basement_apartment.
			"Someone has already thought of it, but there don't
			seem to be any hidden nooks behind the wallpaper.
			More searching, then."
		end if.
	end verb.
	verb knock_on does only
		"You knock on" say the this. "in various places, but it
		fails to sound hollow anywhere. So much for that idea."
	end verb.
end the apartment_walls.

the apartment_bookshelf isa object at basement_apartment
	name books
	name book
	name bookshelves
	is not searched.
	description
	verb examine does only
		"None of these books is newer than a century, an endless
		parade of famous poets, philosophers and other classics.
		A treasure in itself, but not what he was looking for."
	end verb.
	verb take does only
		"You browse idly through a couple of books, then put them back.
		This is not the time."
	end verb.
	verb read does only
		"There will be plenty of time for that later. After he shows
		up. After you learn if you still have a future together."
	end verb.
	verb search, look_behind does only
		if this is searched then
			"You've already checked" say the this. "."
		else
			make this searched.
			increase searches of basement_apartment.
			"There's nothing behind the bookshelves except for
			the walls, as far as you can tell. If one of these
			books opened a secret passage, there would be
			nowhere for it to go. That's not it."
		end if.
	end verb.
end the apartment_bookshelf.

the coffee_table isa object at basement_apartment
	name coffee table
	is not searched.
	description
	verb examine does only
		"It's a heavy piece of furniture, round in shape, with a
		polished top and ornate legs that curve elegantly. The dust
		on it has been disturbed, mute evidence of a previous search."
	end verb.
	verb search, look_under does only
		if this is searched then
			"You've already checked" say the this. "."
		else
			make this searched.
			increase searches of basement_apartment.
			"The floorboards underneath bear scratch marks,
			evidence that the table has been moved around.
			Not much else there either."
		end if.
	end verb.
	verb flip does only
		"Actually, the table is kind of too heavy for that, but you
		lift it enough to peek at the underside. It's featureless."
	end verb.
end the coffee_table.

the armchair isa object at basement_apartment
	name armchairs
	name armchair
	name arm chairs
	name arm chair
	is not searched.
	description
	verb examine does only
		"Nicely patterned textile upholstery covers a pair of big,
		heavy armchairs of the kind that unfold into small beds."
	end verb.
	verb unfold does only
		"You huff and puff, but the frames don't yield.
		The mechanisms must be rusted shut."
	end verb.
	verb fold does only
		"Both armchairs are already folded."
	end verb.
	verb search, look_behind, look_under does only
		if this is searched then
			"You've already checked" say the this. "."
		else
			make this searched.
			increase searches of basement_apartment.
			"The massive armchairs look made to hide something
			with -- or for that matter within -- their bulk,
			but signs of rough treatment are all you find.
			Clearly you weren't the first one to think of it.
			Got to look elsewhere."
		end if.
	end verb.
end the armchair.

the apartment_fixtures isa object at basement_apartment
	name fixtures
	name kitchenette
	name small shower
	is not searched.
	description
	verb examine does only
		"Pretty obvious that the kitchenette and shower were
		never meant to be used seriously. Maybe some absent-minded
		professor once lived here, eating out more often than not,
		and washing... well, better not think of that too deeply."
	end verb.
	verb search does only
		if this is searched then
			"You've already checked" say the this. "."
		else
			make this searched.
			increase searches of basement_apartment.
			"The kitchenette and shower are relatively untouched
			by the ravages of time, but apart from a trove of
			small domestic items (themselves of some value as
			antiques), there is nothing worthwhile. No hidden
			compartments here. Someplace else, hopefully."
		end if.
	end verb.
	verb look_behind, look_under does only
		"The walls and floors in there look solid. A dead end."
	end verb.
end the apartment_fixtures.

the apartment_floor isa object at basement_apartment
	name floor
	name carpet
	name floorboards
	name floorboard
	is not searched.
	description
	verb examine does only
		"The once-luxurious persian carpet, now a ruin, has been
		rolled up in a corner, revealing the rotting floorboards,
		and some of the dust has been swept, for better or worse."
	end verb.
	verb search, look_under does only
		if this is searched then
			"You've already checked" say the this. "."
		else
			make this searched.
			increase searches of basement_apartment.
			"Some of the looser floodboards have been already
			pried open. You inspect the space under them again,
			just in case, but there's nothing of value. There
			must be something else."
		end if.
	end verb.
	verb knock_on does only
		"You knock on" say the this. "in various places, but it
		fails to sound hollow anywhere. So much for that idea."
	end verb.
end the apartment_floor.

the apartment_ceiling isa object at basement_apartment
	name ceiling
	is not searched.
	description
	verb examine does only
		"Good thinking. Sadly, the ceiling is just smooth and plain."
	end verb.
	verb search, look_behind does only
		if this is searched then
			"You've already checked" say the this. "."
		else
			make this searched.
			increase searches of basement_apartment.
			"You can easily reach the ceiling by perching on
			the furniture, but it's just as plain as it
			appears. No dice."
		end if.
	end verb.
	verb look_under does only
		"Under the ceiling there's the rest of the apartment.
		Not very helpful."
	end verb.
	verb knock_on does only
		"You knock on" say the this. "in various places, but it
		fails to sound hollow anywhere. So much for that idea."
	end verb.
end the apartment_ceiling.

when searches of basement_apartment >= 4 then
	schedule the_end at basement_apartment after 0.
end when.

event the_end
	"$pYou straighten up and dust off your hands, breathing heavily.
	The room seems to mock your efforts. Maybe you were wrong after all.
	Maybe he already got what he wanted. What if he doesn't even want
	you back?
	$pThen you see the light. It feels as if your feet have left the
	ground as you rush to... yes! There it is! You carefully pull out
	a large, heavy jewel box. It can't be anything else. He described
	it to you often enough.
	$pIt's also the accursed thing you two argued over. The reason you
	left. Suddenly the room is dark again, and a voice whispers, smash
	it. Burn it. Whatever's in this box ruined years of your life.
	$pBut then you'd never forgive yourself. Clutching the box carefully
	to your chest, you make your way back across the basement, then up
	the stairs and into the bedroom. It looks good on the desk, you say
	to yourself. He's not back yet, so you lie down on the bed to rest
	for a moment, basking in his presence.
	$pYou drift to sleep dreaming of your love."
	style emphasized.
	"$p*** The End ***"
	style normal.
	quit.
end event.