message UNKNOWN_WORD: "You don't need the word '$1' in this story."

add to every thing
	verb look_behind does
		"There's nothing behind " say the this. ".$n"
	end verb.
	verb look_under does
		"There's nothing under " say the this. ".$n"
	end verb.
end add to.
syntax look_behind = 'look' 'behind' (obj)
	where obj isa thing
	else "It doesn't make sense to look behind that."
syntax look_under = 'look' 'under' (obj)
	where obj isa thing
	else "It doesn't make sense to look under that."

add to every object
	verb fold does
		"That promises to be a fruitless course of action.$n"
	end verb.
	verb unfold does
		"That promises to be a fruitless course of action.$n"
	end verb.
end add to.
syntax fold = fold (obj)
	where obj isa object
	else "That doesn't even make sense."
syntax unfold = unfold (obj)
	where obj isa object
	else "That doesn't even make sense."

add to every object
	verb put_in when obj2
		does "That doesn't seem to work."
	end verb.
end add to.
syntax put_in = 'put' (obj) 'in' (obj2)
	where obj2 isa object
	else "That doesn't even make sense."
syntax put_in = 'stick' (obj) 'in' (obj2).

add to every thing
	verb 'do', wash does
		"That promises to be a fruitless course of action.$n"
	end verb.
	verb push does
		"Nothing obvious happens."
	end verb.
	verb press does
		say the this. "isn't something you can press."
	end verb.
end add to.
syntax 'do' = 'do' (obj)
	where obj isa thing
	else "It doesn't make sense to do that."
syntax wash = wash (obj)
	where obj isa thing
	else "It doesn't make sense to wash that."
syntax push = push (obj)
	where obj isa thing
	else "It doesn't make sense to push that."
syntax press = press (obj)
	where obj isa thing
	else "It doesn't make sense to press that."
	
verb yell does "This feels like the wrong time and place for it." end verb.
syntax yell = yell.
	yell = shout.
	yell = scream.
	yell = call out.

verb knock does "It's not obvious what to knock on." end verb.
add to every object
	verb knock_on does
		"You knock on" say the this. "with no obvious results."
	end verb.
end add to.
syntax knock = knock.
	knock_on = knock on (obj).
	
verb listen does "You hear nothing unexpected." end verb.
verb smell does "You smell nothing unexpected." end verb.
add to every object
	verb listen_to does
		"You hear nothing unexpected."
	end verb.
	verb sniff_at does
		"You smell nothing unexpected."
	end verb.
end add to.
syntax listen = listen.
	smell = smell.
	smell = sniff.
	listen_to = 'listen' 'to' (obj).
	sniff_at = smell (obj).
	sniff_at = sniff (obj).

add to every thing
	verb read does
		say the this. "isn't exactly reading material."
	end verb.
end add to.
syntax read = 'read' (obj)
	where obj isa thing
	else "It doesn't make sense to try and read that."


the maple_leaf isa object at limbo
	name maple leaf
	is portable.
	verb examine does only
		"It's a big, beautiful maple leaf, with its broad
		pointy contour and all the colors of autumn."
	end verb.
end the maple_leaf.

the postcard isa object at limbo
	name postcard
	name card
	is portable.
	is not folded.
	mentioned
		"postcard"
		if this is folded then "(folded)" end if.
	verb examine does only
		"It's a sturdy bit of card stock, now warped with age.
		The photo on its face depicts the city in its former
		glory. A year is stamped in the corner: 2016."
		if this is folded then
			"$pThe postcard has been carefully folded in half."
		end if.
	end verb.
	verb read does only
		"There aren't many words on the postcard. The photo on
		its face depicts the city in its former glory, with a
		year stamped in the corner: 2016."
	end verb.
	verb fold does only
		if this is folded then
			"Better not fold it any more than it already is."
		else
			make this folded.
			"You carefully fold the postcard in half, not
			too tight."
		end if.
	end verb.
	verb unfold does only
		if this is folded then
			make this not folded.
			"You carefully unfold the postcard. It doesn't
			look much worse for the wear."
		else
			"It's already unfolded."
		end if.
	end verb.
end the postcard.