; COMMENTS TO FLAGS
;
; FLAG 1 is ON if front door is open
; FLAG 2 is ON if ID-card has been shown
; FLAG 3 is ON when wastebasket has been searched
; FLAG 4 is ON when books have been lifted
; FLAG 5 is ON when bookcase has been lifted
; FLAG 6 is ON when cord has been pulled
; FLAG 7 is ON when window has been opened
; FLAG 8 is ON when butler has been asked about the body
; FLAG 9 is ON when window has been closed
; FLAG 10 is ON when question has been asked
; FLAG 11 is ON when closets have been opened

COMMAND ANY
AtLocation 3 (* Main hall *)
Present 300 (* Police officer *)
FlagOFF 2 (* Card has not been shown yet *)
VerbIsDirection
PrintMessage 3 (* Officer will not let you through *)
DoneWithTurn
END_COMMAND

COMMAND SHOW CARD TO OFFICER
AtLocation 3 (* Main hall *)
Present 300 (* Police officer *)
FlagOFF 2 (* Card has not been shown yet *)
IsCarrying 205 (* ID card *)
GoToRoom 16 (* Fireplace in livingroom *)
PrintMessage 4 (* The officer escorts you to the room *)
TurnFlagON 2
DoneWithTurn
END_COMMAND

COMMAND SHOW CARD TO OFFICER
FlagON 2 (* Has been done *)
PrintMessage 8 (* Have done that *)
DoneWithTurn
END_COMMAND

COMMAND SHOW CARD
ReDirectTo SHOW CARD TO OFFICER
END_COMMAND

COMMAND PRESS HANDLE
FlagOFF 1 (* Door is not open *)
AtLocation 2 (* At front door *)
SwapLocations 200 202 (* Open door *)
ChangePassageway 2 3 (* Door is now open to the south *)
PrintMessage 1 (* The door is open *)
TurnFlagON 1 (* Door is open *)
DoneWithTurn
END_COMMAND

COMMAND PRESS HANDLE
FlagON 1 (* Door is already open *)
PrintMessage 2 (* The door is already open *)
DoneWithTurn
END_COMMAND

COMMAND OPEN DOOR
ReDirectTo PRESS HANDLE
END_COMMAND

COMMAND KILL ANY
PrintMessage 5 (* Sick idea! *)
DoneWithTurn
END_COMMAND

COMMAND GET ANY
NOUNIsCreature
PrintMessage 6 (* You cannot do that *)
DoneWithTurn
END_COMMAND

COMMAND KISS ANY
NOUNIsCreature
Present 310 (* Dead body *)
PrintMessage 15 (* Pervert! *)
DoneWithTurn
END_COMMAND

COMMAND KISS ANY
NOUNIsCreature
PrintMessage 6 (* You cannot do that *)
DoneWithTurn
END_COMMAND

COMMAND OPEN HAND
AtLocation 17
Present 206 (* Hand with hair *)
SwapLocations 206 207 (* Swap closed hand with open hand *)
PutInCurrentRoom 208 (* Wisp of hair *)
PrintMessage 7 (* You open the victim's hand *)
BlankLine
PrintMessage 37 (* You earned 10 p. *)
PlusScore 10
DoneWithTurn
END_COMMAND

COMMAND OPEN HAND
AtLocation 17
Present 207 (* Open hand *)
PrintMessage 8 (* Nothing to open *)
DoneWithTurn
END_COMMAND

COMMAND GET CANDLESTICK
AtLocation 17
Present 209 (* Candlestick *)
NOT IsCarrying 209 (* Candlestick *)
GetIt 209 (* Candlestick *)
PrintMessage 9 (* You take the candlestick *)
DoneWithTurn
END_COMMAND

COMMAND EMPTY WASTEBASKET
FlagOFF 3
AtLocation 30
Present 210 (* Wastebasket *)
PutInCurrentRoom 211 (* Letter *)
PrintMessage 10 (* You find a letter *)
TurnFlagON 3
BlankLine
PrintMessage 37 (* You earned 10 p.*)
PlusScore 10
DoneWithTurn
END_COMMAND

COMMAND EMPTY WASTEBASKET
FlagON 3 (* Has been done *)
PrintMessage 12 (* You find nothing of interest *)
DoneWithTurn
END_COMMAND

COMMAND GET ASHTRAY
AtLocation 30
PrintMessage 11 (* No reason *)
DoneWithTurn
END_COMMAND

COMMAND GET TOOLS
AtLocation 10
PrintMessage 11 (* No reason *)
DoneWithTurn
END_COMMAND

COMMAND LIFT BOOKS
FlagOFF 4 (* Books have not been lifted yet *)
AtLocation 26
PutInCurrentRoom 215 (* Magazine *)
PrintMessage 14
TurnFlagON 4
BlankLine
PrintMessage 37 (* You earned 10p.*)
PlusScore 10
DoneWithTurn
END_COMMAND

COMMAND LIFT BOOKS
AtLocation 26
FlagON 4 (* Books have been lifted *)
PrintMessage 12 (* You find nothing of interest *)
DoneWithTurn
END_COMMAND

COMMAND LIFT CARPET
AtLocation 3
PrintMessage 12 (* You find nothing of interest *)
DoneWithTurn
END_COMMAND

COMMAND SMASH MIRROR
ATLocation 39
Present 218 (* Mirror *)
PrintMessage 16 (* Are you sure *)
PromptForYES
BlankLine
SwapLocations 218 219 (* Broken mirror *)
PutInCurrentRoom 217 (* Key *)
PrintMessage 17 (* You smash the mirror and find a key *)
BlankLine
PrintMessage 41 (* You earned 25 p. *)
PlusScore 25
DoneWithTurn
END_COMMAND

COMMAND SMASH MIRROR
AtLocation 3
OR
AtLocation 5
OR
AtLocation 20
OR
AtLocation 29
PrintMessage 16 (* Are you sure *)
PromptForYES
BlankLine
PrintMessage 42 (* You are hit by one of the pieces *)
EndGame
DoneWithTurn
END_COMMAND

COMMAND SOLUTION
ScoreLT 100
PrintMessage 18
EndGame
DoneWithTurn
END_COMMAND

COMMAND SOLUTION
ScoreEquals 100
FlagOFF 10 (* Question has not been asked *)
PrintMessage 16 (* Are you sure *)
PromptForYES
BlankLine
AskQuestion 1 (* Who killed her? *)
TurnFlagON 10
AnswerIsCorrect
TurnFlagOFF 10
PrintMessage 19 (* Correct answer! *)
WinGame
DoneWithTurn
END_COMMAND

COMMAND SOLUTION
FlagON 10
PrintMessage 20 (* Wrong answer! *)
EndGame
DoneWithTurn
END_COMMAND

COMMAND OPEN CHEST
Present 217 (* Key *)
Present 220 (* Chest *)
PrintMessage 21 (* You open the chest *)
PrintMessage 40 (* You find a note *)
SwapLocations 220 221 (* Swap closed chest with open chest *)
PutInCurrentRoom 236 (* Diary *)
BlankLine
PrintMessage 37 (* You earn 10p. *)
PlusScore 10
DoneWithTurn
END_COMMAND

COMMAND OPEN CHEST
NOT Present 217 (* Key *)
PrintMessage 22 (* Can't do that *)
DoneWithTurn
END_COMMAND

COMMAND OPEN CHEST
Present 217 (* Key *)
Present 221 (* Open chest *)
PrintMessage 23 (* It is already open! *)
DoneWithTurn
END_COMMAND

COMMAND CLOSE CHEST
Present 221 (* Open chest *)
SwapLocations 221 220 (* Swap open chest with closed chest *)
PrintMessage 24 (* You close the chest *)
DoneWithTurn
END_COMMAND

COMMAND CLOSE CHEST
Present 220 (* Closed chest *)
PrintMessage 25 (* It is already closed! *)
DoneWithTurn
END_COMMAND

COMMAND GET CHEST
NOUNPresent
PrintMessage 11 (* Not needed for the solving *)
DoneWithTurn
END_COMMAND

COMMAND GET CHEST
NOT NOUNPresent
PrintMessage 26 (* The chest is not here *)
DoneWithTurn
END_COMMAND

COMMAND LIFT BOOKCASE
AtLocation 17
Present 223 (* Bookcase *)
FlagOFF 5 (* Bookcase has not been lifted yet *)
PrintMessage 27 (* Not wise *)
PromptForYES
Blankline
PrintMessage 28 (* You find a secret passage *)
ChangePassageway 2 41 (* You can now enter the passage *)
SwapLocations 223 224 (* Secret door is open *)
TurnFlagON 5
BlankLine
PrintMessage 41 (* You earned 25 p. *)
PlusScore 25
DoneWithTurn
END_COMMAND

COMMAND LIFT BOOKCASE
AtLocation 17
FlagON 5 (* Has been done *)
PrintMessage 29 (* You have done that *)
DoneWithTurn
END_COMMAND

COMMAND LIFT TABLE
AtLocation 11
PrintMessage 27 (* Not wise *)
PromptForYES
Blankline
PrintMessage 47 (* You get a slipped disk *)
EndGame
DoneWithTurn
END_COMMAND

COMMAND PULL CORD
AtLocation 41
FlagOFF 6 (* Not done yet *)
ChangePassageway 2 39 (* You can now enter the wine cellar *)
PutInCurrentRoom 225 (* Secret door *)
PrintMessage 30 (* The door is now open *)
TurnFlagON 6
DoneWithTurn
END_COMMAND

COMMAND PULL CORD
AtLocation 41
FlagON 6
PrintMessage 29 (* You have done that *)
DoneWithTurn
END_COMMAND

COMMAND OPEN WINDOW
AtLocation 17
FlagOFF 7
PrintMessage 31 (* You open the window and see some footprints *)
TurnFlagON 7
SwapLocations 227 228 (* Window is now open *)
BlankLine
PrintMessage 37 (* You earned 10p.*)
PlusScore 10
DoneWithTurn
END_COMMAND

COMMAND OPEN WINDOW
AtLocation 17
FlagON 7 (* Has been done *)
PrintMessage 29 (* You have done that *)
DoneWithTurn
END_COMMAND

COMMAND OPEN WINDOW
AtLocation 17
FlagON 8 (* Has been done *)
PrintMessage 29 (* You have done that *)
DoneWithTurn
END_COMMAND

COMMAND UNLOCK WINDOW
ReDirectTo OPEN WINDOW
END_COMMAND

COMMAND CLOSE WINDOW
AtLocation 17
FLagOFF 8
PrintMessage 38 (* You close the window *)
SwapLocations 228 227 (* Window is now closed *)
TurnFlagON 8
DoneWithTurn
END_COMMAND

COMMAND CLOSE WINDOW
AtLocation 17
FlagON 8 (* Has been done *)
PrintMessage 29 (* You have done that *)
DoneWithTurn
END_COMMAND

COMMAND ASK BUTLER ABOUT BODY
Present 308 (* Butler *)
FlagOFF 8
PrintMessage 32 (* Butler tells how he found the body *)
TurnFlagON 8
DoneWithTurn
END_COMMAND

COMMAND ASK BUTLER ABOUT BODY
NOT Present 308 (* Butler *)
FlagOFF 8
PrintMessage 33 (* He is not here *)
DoneWithTurn
END_COMMAND

COMMAND ASK BUTLER ABOUT BODY
FlagON 8
PrintMessage 29 (* You have done that already *)
DoneWithTurn
END_COMMAND

COMMAND DRINK WINE
Present 229 (* Wine *)
PrintMessage 34 (* Ahh! *)
SwapLocations 229 230
DoneWithTurn
END_MESSAGE

COMMAND DRINK WINE
Present 230
PrintMessage 29 (* You have done that *)
DoneWithTurn
END_COMMAND

COMMAND GO KITCHEN
FlagON 2 (* You are in the house *)
GoToRoom 10
LookAtRoom
DoneWithTurn
END_COMMAND

COMMAND GO LIVINGROOM
FlagON 2 (* You are in the house *)
GoToRoom 12
LookAtRoom
DoneWithTurn
END_COMMAND

COMMAND GO LIBRARY
FlagON 2 (* You are in the house *)
GoToRoom 17
LookAtRoom
DoneWithTurn
END_COMMAND

COMMAND GO BEDROOM
FlagON 2 (* You are in the house *)
GoToRoom 21
LookAtRoom
DoneWithTurn
END_COMMAND

COMMAND GO CELLAR
FlagON 2 (* You are in the house *)
GoToRoom 36
LookAtRoom
DoneWithTurn
END_COMMAND

COMMAND GO ANY
FlagOFF 2 (* You are NOT in the house *)
PrintMessage 36 (* You must enter first *)
DoneWithTurn
END_COMMAND

COMMAND GO ANY
NOUNPresent
PrintMessage 35 (* Cannot use GO here *)
DoneWithTurn
END_COMMAND

COMMAND REMOVE BOOKS
AtLocation 17
PrintMessage 39 (* Haven't got the time *)
DoneWithTurn
END_COMMAND

COMMAND READ BOOKS
AtLocation 17
PrintMessage 39 (* Haven't got the time *)
DoneWithTurn
END_COMMAND

COMMAND ASK RICKS ABOUT ALIBI
NOUNIsNumber 303
NOUNPresent
PrintMessage 45 (* Mrs. Ricks confirms the inspector *)
DoneWithTurn
END_MESSAGE

COMMAND ASK OFFICER ABOUT ALIBI
NOUNIsCreature
NounPresent
PrintMessage 46 (* The officer confirms the alibies *)
DoneWithTurn
END_COMMAND

COMMAND ASK ANY ABOUT ALIBI
NOUNIsCreature
NOUNPresent
NOT NOUNIsNumber 310 (* Body *)
NOT NOUNIsNumber 303 (* Mrs. Ricks *)
NOT NOUNIsNumber 300 (* Police officer *)
PrintMessage 43 (* Alibies are confirmed *)
DoneWithTurn
END_MESSAGE

COMMAND ASK ANY ABOUT ALIBI
NOUNIsCreature
NOUNPresent
NOUNIsNumber 310 (* Body *)
PrintMessage 44 (* She is dead, Turkey! *)
DoneWithTurn
END_MESSAGE

COMMAND OPEN CLOSET
AtLocation 18 (* Guest room *)
OR
AtLocation 21 (* Bedroom *)
OR
AtLocation 24 (* Guest room *)
OR
AtLocation 26 (* Butler's room *)
OR
AtLocation 33 (* Lodger's room *)
PrintMessage 48 (* You search the closet, but find nothing *)
DoneWithTurn
END_COMMAND

COMMAND TURN ON TAPS
AtLocation 23
PrintMessage 49 (* There is no time for a bath. *)
DoneWithTurn
END_COMMAND

COMMAND FILL TUB
ReDirectTo TURN ON TAPS
END_COMMAND

COMMAND GET WINES
AtLocation 39
PrintMessage 50 (* Thief! *)
DoneWithTurn
END_COMMAND