#WIN

/*
 *      "normal.adv"
 *      Diese Datei enthält die häufigsten Befehle, die in Adventures
 *      vorkommen, die aber keine Standard-Befehle von T.A.G. sind.
 *
 *      Daher wird empfohlen, die Datei mit
 *
 *              #DAT 'normal.adv'
 *
 *      einzubinden. Die meisten Befehle sind sehr einfach, da sie
 *      nur eine passende Antwort geben, ohne etwas zu bewirken.
 *
 *      Selbstverständlich kann diese Datei je nach Adventure verändert
 *      und an das Projekt angepaßt werden.
 */

/*
 *      Richtungen
 */

Richtung  N     'norden'        'n' *
Richtung  NO    'nordosten'     'no' *
Richtung  O     'osten'         'o' *
Richtung  SO    'südosten'      'so' *
Richtung  S     'süden'         's' *
Richtung  SW    'südwesten'     'sw' *
Richtung  W     'westen'        'w' *
Richtung  NW    'nordwesten'    'nw' *
Richtung  H     'oben'          'hoch'
Richtung  R     'unten'         'runter'
Richtung  Rein  'drinnen'       'rein'
Richtung  Raus  'draussen'      'raus'

Synonym 'h' 'hoch'
Synonym 'r' 'runter'
Synonym 'rauf' 'hoch'

/*
 *      globale Hilfsvariablen
 */

Flagge  Aux
Flagge  xFlg
Flagge  yFlg
Flagge  zFlg

ObjVar  xObj
ObjVar  yObj
ObjVar  zObj

RaumVar xRaum
RaumVar yRaum
RaumVar zRaum

RitgVar xRitg
RitgVar yRitg
RitgVar zRitg

ZustVar xZust
ZustVar yZust
ZustVar zZust

/*
 *      Befehle, die (evtl.) etwas bewirken
 */

ObjAttr essbar

Bef     essen
Name    'essen'
Verb    'iss' 'esse' 'verzehre' 'verschlinge' 'vertilge' 'iss auf' 'esse auf'
Verb    'verleibe dir ein'
Syntax  dasObj (BeiMir)
Ausf
  Bed (aObj Essbar)
        '[Den aObj] kannst du nicht essen.'
  ObjNach aObj Nirwana
  Puffer  'Du ißt [den aObj] auf.'
EndeAusf


Bef     trinken
Name    'trinken'
Verb    'trinke' 'schlürfe'
Syntax  dasObj
Ausf
  Bed (aObj Fluid)
        'Das kann man beim besten Willen nicht trinken.'
  Text  '[Der aObj] [wird] dir bestimmt nicht schmecken.'
EndeAusf


Bef     gehen_in
Name    'gehen'
Verb    'gehe' 'laufe' 'bewege dich'
Syntax  in dasObj (Tür)
Präp    'durch' 'über'
Ausf    betreten


Bef     gehen_zu
Name    'gehen'
Verb    'gehe' 'laufe' 'bewege dich'
Syntax  zu demObj (Tür)
Ausf
  Text  'Dorthin kannst du nicht gehen.'
EndeAusf



Bef     verlassen
Name    'verlassen'
Verb    'verlasse'
Syntax  dasObj
Ausf    steigen_von


ObjAttr herumschiebbar

Bef     schieben_nach
Name    'schieben'
Verb    'schiebe' 'bewege' 'verschiebe'
Syntax  dasObj (nichtBeiMir) nachRitg
Ausf
  Bed (aObj herumschiebbar)
        'Du kannst [den aObj] nicht in der Gegend herumschieben.'
  SeiRaum xRaum aRaum aRitg
  Wenn /(xRaum = 0) dann
    Text  'Du schiebst [den aObj] nach [aRitg].[#]'
    ObjNach aObj xRaum
  Ende
  Ausf gehen aRitg
EndeAusf


Bef     geben
Name    'geben'
Verb    'gib' 'gebe' 'schenke' 'biete an'
Syntax  dasObj (BeiMir) demObj (Person)
Ausf
  Bed (aObj2 Person)
        'Glaubst du wirklich, daß [der aObj2] [den aObj] gerne haben
        [möchte/möchten aObj2]?'
  Text  '[Der aObj2] lehn[t] [den aObj] höflich ab.'
EndeAusf

Pseudo  gegeben geben


Bef     zeigen
Name    'zeigen'
Verb    'zeige'
Syntax  dasObj (BeiMir) demObj (Person)
Ausf
  Bed (aObj2 Person)
        '[Der aObj2] [ist] unbeeindruckt.'
  Text  '[Der aObj2] schau[t] [den aObj] an, [ist] aber nicht im geringsten
        beeindruckt.'
EndeAusf

Pseudo  gezeigt zeigen


Bef     werfen
Name    'werfen'
Verb    'werfe' 'wirf' 'schmeisse' 'schleudere'
Syntax  dasObj (BeiMir) auf dasObj (inSicht)
Präp    'in' 'über' 'an'
Ausf
  Bed /(aObj Person)
        'Es gibt bestimmt einen besseren Weg, um [den aObj] auf dich
        aufmerksam zu machen.'
  Text  'Das ist wahrscheinlich keine so gute Idee.'
EndeAusf


Bef     füllen
Name    'füllen'
Verb    'fülle'
Syntax  dasObj (Behälter) mit demObj (Fluid)
Ausf
  Bed (aObj2 Fluid)
        '[Der aObj2] [ist] keine Flüssigkeit.'
  Bed (aObj Behälter)
        'In [den aObj] kann man nichts einfüllen.'
  Text  'Das macht doch keinen Sinn.'
EndeAusf


Bef     füllen_in
Name    'füllen'
Verb    'fülle' 'schütte' 'gieße' 'fülle ein'
Syntax  in dasObj (Behälter) dasObj (Fluid)
Ausf    füllen

/*
 *      Befehle, die meist nur eine dumme Antwort geben
 */

Bef     ziehen
Name    'ziehen'
Verb    'ziehe' 'zerre' 'zupfe'
Syntax  dasObj
Ausf
  Bed /(aObj Person)
        'Besser nicht, [dem aObj] gefällt das bestimmt nicht.'
  Bed (aObj.Gew > MaxGew) oder (aObj Deko)
        'Du ziehst ein wenig an [dem aObj].'
  Text  '[Der aObj] beweg[t] sich kein Stück.'
EndeAusf

Bef     ziehen_an
Name    'ziehen'
Verb    'ziehe' 'zerre' 'zupfe'
Syntax  an demObj
Ausf    ziehen


Bef     schieben
Name    'schieben'
Verb    'schiebe' 'verschiebe'
Syntax  dasObj
Ausf
  Bed /(aObj Person)
        'Besser nicht, [dem aObj] gefällt das bestimmt nicht.'
  Bed (aObj.Gew > MaxGew) oder (aObj Deko)
        'Du schiebst [den aObj] hin und her - ohne sichtbaren Erfolg.'
  Text  '[Der aObj] beweg[t] sich kein Stück.'
EndeAusf


Bef     drücken
Name    'drücken'
Verb    'drücke'
Syntax  dasObj
Ausf
  Bed /(aObj Person)
        '[Der aObj] [ist] nicht gerade begeistert von deiner
        Zuneigung für [ihn].'
  Text  'Du drückst [den aObj] ganz fest.'
EndeAusf


Bef     drehen
Name    'drehen'
Verb    'drehe' 'verdrehe'
Syntax  dasObj
Ausf
  Text  'An [dem aObj] gibt es nichts zu drehen.'
EndeAusf

Bef     drehen_an
Name    'drehen'
Verb    'drehe'
Syntax  an demObj
Ausf    drehen


Bef     benutzen *
Name    'benutzen'
Verb    'benutze' 'wende an' 'setze ein'
Syntax  dasObj mit demObj (evtl)
Ausf
  Text  'Bitte sage genau, wie ich [den aObj] benutzen soll.'
EndeAusf


Bef     bewegen *
Name    'bewegen'
Verb    'bewege' 'manipuliere'
Ausf
  Text  'Bitte sage genau, wie ich [den aObj] bewegen soll. Soll ich [es]
        drehen, schieben oder ziehen?'
EndeAusf

Bef     hier_graben
Name    'graben'
Verb    'grabe' 'buddele' 'wühle'
Syntax  in demObj
Ausf
  Text  'Der Boden hier ist zum Graben ungeeignet.'
EndeAusf

Bef     graben
Name    'graben'
Verb    'grabe' 'buddele' 'buddel' 'wühle'
Syntax  in demObj mit demObj (evtl BeiMir)
Ausf
  Text  'Dort läßt sich nicht gut graben.'
EndeAusf


Bef     klettern
Name    'klettern'
Verb    'klettere' 'klettre'
Syntax  auf dasObj (NichtBeiMir)
Ausf
  Bed (aObj.Gew > MaxGew) oder (aObj Deko)
        'Auf [den aObj] kannst Du schlecht klettern.'
  Text  'Auf den [aObj] zu klettern ist erstens gefährlich und zweitens
        bringt es nichts.'
EndeAusf


Bef     springen
Name    'springen'
Verb    'springe' 'hüpfe' 'schwinge dich'
Syntax  über dasObj
Präp    'in' 'auf'
Ausf
  Text  'Fällt dir im Moment nichts Besseres ein?'
EndeAusf

Bef     binden
Name    'binden'
Verb    'binde' 'knote' 'binde fest' 'knote fest'
Syntax  dasObj an dasObj
Ausf
  Text  'Du kannst doch [keinen aObj] an [den aObj2] binden!'
EndeAusf

Pseudo  angebunden binden

Bef     lösen
Name    'lösen'
Verb    'löse' 'binde los' 'binde ab' 'knote ab' 'knote' 'binde' 'knote los'
Syntax  dasObj von demObj (evtl)
Ausf
  Text  '[Der aObj] [läßt/lassen] sich nicht lösen.'
EndeAusf


Bef     verbrennen
Name    'verbrennen'
Verb    'verbrenne'
Syntax  dasObj
Ausf
  Text  'Nein, du kleiner Feuerteufel.'
EndeAusf


Bef     zerstören
Name    'kaputt machen'
Verb    'zerstöre' 'zerbreche' 'breche auf' 'zerreiße' 'reiße auf'
Verb    'mache kaputt' 'zerschmettere'
Syntax  dasObj mit demObj (evtl BeiMir)
Ausf
  Text  'Was soll diese blinde Zerstörungswut?'
EndeAusf


Bef     schneiden
Name    'schneiden'
Verb    'schneide' 'zerschneide' 'schneide ab' 'zertrenne'
Syntax  dasObj mit demObj (evtl BeiMir)
Ausf
  Text  'An [dem aObj] herumzuschnippeln würde wahrscheinlich nichts bringen.'
EndeAusf


Bef     schwimmen
Name    'schwimmen'
Verb    'schwimme' 'tauche'
Ausf
  Text  'Hier ist ein bißchen wenig Wasser.'
EndeAusf


Bef     wedeln
Name    'wedeln'
Verb    'wedele' 'winke' 'schwinge' 'schwenke'
Syntax  dasObj (BeiMir)
Ausf
  Bed /(aObj Angezogen)
        'Dazu müßtest du [den aObj] erst ausziehen.'
  Text  'Du siehst ziemlich lächerlich aus, als du [den aObj] schwenkst.'
EndeAusf

Bef     wedeln_mit
Name    'wedeln'
Verb    'wedele' 'winke' 'schwinge' 'schwenke'
Syntax  mit demObj (BeiMir)
Ausf    wedeln


Bef     schütteln
Name    'schütteln'
Verb    'schüttele'
Syntax  dasObj
Ausf
  Bed /(aObj.Gew > MaxGew)
        '[Der aObj] schütteln? Denk nochmal nach.'
  Text  'Ich schüttle [den aObj].'
EndeAusf


Bef     reiben
Name    'reiben'
Verb    'reibe' 'rubbele'
Syntax  dasObj
Ausf
  Text  'Nichts besonderes passiert, als du an dem [aObj] reibst.'
EndeAusf

Bef     reiben_an
Name    'reiben'
Verb    'reibe' 'rubbele'
Syntax  an demObj
Ausf    reiben


Bef     putzen
Name    'putzen'
Verb    'putze' 'säubere' 'mache sauber' 'wische'
Syntax  dasObj mit demObj (evtl)
Ausf
  Text  '[Der aObj] sieht nun ein wenig sauberer aus.'
EndeAusf


Bef     spielen
Name    'spielen'
Verb    'spiele' 'blase'
Syntax  dasObj
Ausf
  Text  '[Der aObj] [ist] als Musikinstrument nicht besonders geeignet.'
EndeAusf

Bef     spielen_auf
Name    'spielen'
Verb    'spiele'
Syntax  auf demObj
Ausf    spielen


Bef     spielen_mit
Name    'spielen'
Verb    'spiele' 'spiele herum'
Syntax  mit demObj
Ausf
  Bed /(aObj Person)
        '[Der aObj] [hat] jetzt keine Zeit für Spielereien.'
  Text  'Du zerstreust dich ein wenig, indem du mit [dem aObj] herumspielst.'
EndeAusf


Bef     kleben
Name    'kleben'
Verb    'klebe''klebe fest' 'pappe' 'bappe'
Syntax  dasObj (BeiMir) auf dasObj
Ausf
  Text  '[Der aObj] kleb[t] nicht besonders gut.'
EndeAusf


Bef     berühren
Name    'berühren'
Verb    'berühre' 'betaste' 'befühle'
Syntax  dasObj
Ausf
  Bed /(aObj Person)
        'Kannst du deine Hände nicht bei dir lassen?'
  Text  'Du fühlst nichts Außergewöhnliches, als du [den aObj] betastest.'
EndeAusf

Bef     fühlen_an
Name    'fühlen'
Verb    'fühle' 'taste'
Syntax  an demObj
Ausf    berühren

Bef     berühren_mit
Name    'berühren'
Verb    'berühre' 'betaste' 'befühle'
Syntax  dasObj mit demObj
Ausf
  Text  'Nichts passiert.'
EndeAusf


Bef     riechen
Name    'riechen'
Verb    'rieche' 'schnüffele' 'schnuppere'
Ausf
  Text  'Du riechst nichts Außergewöhnliches.'
EndeAusf

Bef     riechen_an
Name    'riechen'
Verb    'rieche' 'schnüffele' 'schnuppere'
Syntax  an demObj
Ausf
  Text  '[Er aObj] riech[t] wie [ein aObj].'
EndeAusf

Bef     lauschen
Name    'lauschen'
Verb    'lausche' 'höre' 'höre zu'
Ausf
  Text  'Du lauschst gespannt, hörst aber nichts Besonderes.'
EndeAusf

Bef     zuhören
Name    'zuhören'
Verb    'lausche' 'höre' 'höre zu'
Syntax  demObj (Person)
Ausf
  Text  'Du hörst [dem aObj] geduldig zu.'
EndeAusf


Bef     schlafen
Name    'schlafen'
Verb    'schlafe' 'schlafe ein' 'ruhe dich aus' 'döse' 'träume'
Ausf
  Text  'Du fühlst dich nicht besonders müde. Außerdem gibt es noch
        einiges zu tun.'
EndeAusf


Bef     aufwachen
Name    'aufwachen'
Verb    'wache auf'
Ausf
  Text  'Gute Idee - aber dies ist leider kein Traum.'
EndeAusf


Bef     aufwecken
Name    'wecken'
Verb    'wecke' 'wecke auf'
Syntax  dasObj (Person)
Ausf
  Text  'Das ist im Moment nicht nötig.'
EndeAusf


ObjAttr Nachschlagewerk

Bef     schlage
Name    'nachschlagen'
Verb    'schlage nach' 'lies nach' 'schaue nach' 'sehe nach' 'sieh nach'
Syntax  dasObj (Allg) in demObj (Nachschlagewerk)
Ausf
  Bed (aObj2 Nachschlagewerk)
        'Dort kann ich nichts nachlesen'
  Text  'Über [den aObj] steht dort nichts.'
EndeAusf


Bef     blättern
Name    'blättern'
Verb    'blättere' 'blättere um' 'schlage um'
Syntax  dasObj
Ausf
  Text  'Darin kann ich nicht blättern.'
EndeAusf


Bef     blättern_in
Name    'blättern'
Verb    'blättere'
Syntax  in demObj
Präp    'durch'
Ausf    blättern


Bef     eingeben
Name    'eingeben'
Verb    'tippe' 'tippe ein' 'gib ein' 'gebe ein' 'gib an' 'gebe an'
Syntax  dasObj (allg) auf demObj
Ausf
  Text  'Auf [dem aObj2] kann man nichts eingeben.'
EndeAusf


Bef     fragen
Name    'fragen'
Verb    'frage' 'befrage'
Syntax  dasObj (Person) nach demObj (Allg)
Ausf
  Bed (aObj Person)
        '[Der aObj] schein[t] nichts zu wissen, jedenfalls sag[t] [er]
        nichts.'
  Text  '[Der aObj] zuck[t] mit den Schultern.'
EndeAusf

Bef     fragen_über
Name    'fragen'
Verb    'frage' 'befrage'
Syntax  dasObj (Person) über dasObj (Allg)
Ausf    fragen


Bef     erzählen
Name    'erzählen'
Verb    'erzähle' 'berichte'
Syntax  demObj (Person) über dasObj (Allg)
Ausf
  Bed (aObj Person)
        'Mußt du jetzt schon [den aObj] mit deinen Geschichten belästigen?'
  Text  '[Der aObj] folg[t]'
  Zufall Aux 0 3
  Jenach Aux
    (1)   Text  'mehr oder weniger gespannt'
    (2)   Text  'höflich interessiert'
    (3)   Text  'mit sichtlichem Desinteresse'
  Ende
  Text  'meinen Ausführungen über [den aObj2].'
EndeAusf

Bef     erzählen_von
Name    'erzählen'
Verb    'erzähle' 'berichte'
Syntax  demObj (Person) von demObj (Allg)
Ausf    erzählen

Bef     reden
Name    'reden'
Verb    'rede' 'sprich' 'spreche'
Syntax  mit demObj (Person) über dasObj (Allg)
Ausf    erzählen


Bef     küssen
Name    'küssen'
Verb    'küsse' 'knutsche'
Syntax  dasObj (Person)
Ausf
  Text  'Du gibst [dem aObj] einen feuchten Kuß.'
EndeAusf


Bef     angreifen
Name    'angreifen'
Verb    'greife an' 'attackiere' 'mache kalt' 'massakriere'
Verb    'töte' 'bringe um' 'erschieße' 'ersteche' 'erwürge'
Syntax  dasobj (Person) mit demObj (evtl BeiMir)
Ausf
  Wenn (aObj = du) dann
    Text  'Wie du willst.'
    Gestorben
  Ende
  Bed (aObj Person)
        '[Der aObj] [ist] doch schon tot.'
  Text  'Mit roher Gewalt kommst du hier - wie so oft im Leben -
        nicht weiter.'
EndeAusf


Bef     schlagen
Name    'schlagen'
Verb    'schlage' 'schlage ein' 'trete' 'trete ein' 'haue'
Syntax  dasObj mit demObj (evtl BeiMir)
Ausf
  Bed /(aObj = ich)
        'Das ist nicht die richtige Zeit für Selbstkasteiung.'
  Wenn (aObj Person) dann
    Ausf angreifen
  sonst
    Ausf zerstören
  Ende
EndeAusf


Bef     kaufen
Name    'kaufen'
Verb    'kaufe' 'bezahle' 'erwerbe' 'bestelle'
Syntax  dasObj
Ausf
  Text  'Hier gibt es nichts zu kaufen.'
EndeAusf


Bef     singen
Name    'singen'
Verb    'singe' 'pfeife' 'jodele'
Ausf
  Text  'Du bist absolut unmusikalisch, das hört man.'
EndeAusf


Bef     hüpfen
Name    'hüpfen'
Verb    'hüpfe' 'springe'
Ausf
  Text  'Du hüpfst ein wenig herum. (Sieht ziemlich bescheuert aus.)'
EndeAusf


Bef     Ja
Name    'Ja sagen'
Verb    'ja' 'jawohl' 'ok'
Ausf
  Text  'Du bist so positiv heute.'
EndeAusf


Bef     Nein
Name    'Nein sagen'
Verb    'nein'
Ausf
  Text  'Das hört sich aber negativ an.'
EndeAusf


Bef     denken
Name    'nachdenken'
Verb    'denke' 'denke nach' 'meditiere'
Ausf
  Text  'Zwecklos.'
EndeAusf


Bef     beten
Name    'beten'
Verb    'bete'
Ausf
  Text  'Deine Gebete werden nicht erhört.'
EndeAusf


Bef     fluchen
Name    'fluchen'
Verb    'fluche' 'scheisse' 'mist' 'kacke' 'schiet' 'verdammt'
Ausf
  Text  'Na, na, was ist denn das für eine Ausdrucksweise?'
EndeAusf


Bef     fluchen_II
Name    'englisch fluchen'
Verb    'shit' 'bullshit' 'fuck'
Ausf
  Text  'Was sollen diese Anglizismen?'
EndeAusf



/*
 *      Meta-Befehle
 */

Bef     #i_lang *
Name    'Inventar'
Verb    'i lang' 'inv_lang' 'inventar lang'
Ausf
  Lösche #inv
  Ausf inventar
EndeAusf


Bef     #i_quer *
Name    'Inventar'
Verb    'i quer' 'inv_quer' 'inventar quer'
Ausf
  Setze #inv
  Ausf inventar
EndeAusf


Bef     objekte
Name    'Objektliste'
Verb    'objekte'
Ausf
  Sei Aux 0
  Schleife iObj
    Wenn (iObj bewegt) dann
      Inkr Aux
      Wenn (Aux = 1) dann
        Text  'Du hast folgende Objekte bereits gehandhabt:[x]'
      Ende
      Text '[:][den iObj]'
      Wenn (iObj BeiMir) dann
        Text  '(in der Hand)'
      Ende
      Wenn (iObj Angezogen) dann
        Text  '(angezogen)'
      Ende
      Wenn (iObj in Nirwana Nirgendwo) dann
        Text  '(verloren)'
      Ende
      MutterObj xObj iObj
      Wenn (xObj = 0) dann
        StammRaum xRaum iObj
        Wenn (xRaum > 0) dann
          Text  '([xRaum])'
        Ende
      sonst
        Wenn (iObj auf xObj) dann
          Text '(auf [dem xObj])'
        Ende
        Wenn (iObj in xObj) dann
          Text '(in [dem xObj])'
        Ende
        Wenn (iObj bei xObj) dann
          Text '(bei [dem xObj])'
        Ende
        Wenn (iObj an xObj) dann
          Text '(an [dem xObj])'
        Ende
      Ende
      Text '[x]'
    Ende
  Ende
  Wenn (Aux = 0) dann
    Text  'Du hast bis jetzt noch keine Objekte gehandhabt.'
  sonst
    Text  '/x'
  Ende
EndeAusf


Bef     räume
Name    'Raumliste'
Verb    'räume' 'orte'
Ausf
  Sei Aux 0
  Text  'Du bist bereits an folgenden Orten gewesen:'
  Schleife xRaum
    Wenn (xRaum besucht) dann
      Inkr Aux
      Wenn (Aux = 1) dann
        Text '[xRaum]/'
      sonst
        Text ', [xRaum]/'
      Ende
    Ende
  Ende
  Text '.[#]'
EndeAusf